Select top(1) * from Table where id <= @id order by id desc

while @l <@r
begin
    -- найти середину
    @id = @l +floor((@r-@l)/2)
    -- найти запись в таблице
    select top(1) @idr = id, @dt = creation_datetime from Table where id <= @id order by id desc
    -- переместить границу
    if(@dt<@tdt)
        @l = @id +1
    else
        @r = @id
end

/*
    Запустите этот скрипт на вашей бд
    Он найдет значение, равное или непосредственно перед целью.
    Обратите внимание, что точность datetime ограничена 3 мс
*/
-- флаг отладки, если установлен, он будет показывать результаты для каждой итерации
declare @debug bit = 0
-- @Table - имя таблицы, в которой вы хотите искать.
declare @Table varchar(128) = 'TableX'
-- @Id - имя столбца идентификатора (id) для таблицы
declare @ID varchar(128) = 'Id'
-- @DateTimeColumn - имя вашего datetime столбца со временем создания в таблице
declare @DateTimeColumn varchar(128) = 'created_dt'
-- это целевое значение даты и времени
declare @TargetDateTime datetime = '2020-01-03 18:23:03'
declare @Sql varchar(max)
set @sql = '
-- это ваш отладочный флаг
declare @debug bit = <debug>
-- это ваше целевое значение
declare @tdt datetime = ''<TargetDateTime>''
-- в этой переменной мы сохраняем промежуточное значение (результат деления)
declare @id bigint
-- это ваши левая и правая границы соответственно
declare @l bigint, @r bigint
-- это переменные, в которых мы храним результаты текущего шага поиска, datetime и идентификатор таблицы соответственно
declare @dt datetime, @idr bigint
-- найти первые «левые» и «правые» значения
select @l = min(<ID>), @r = max(<ID>) from <Table>
while @l < @r
begin
    -- ожидаемый идентификатор
    set @id = @l +floor((@r-@l)/2)
    -- найти значение и идентификатор записи
    select top(1) @dt = <DateTimeColumn>, @idr = <ID> from <Table> where <ID> <= @id order by <ID> desc
    -- если требуется отладка, покажите текущие значения
    if( @debug = 1 )
    begin
        select ''@id'' = @id, ''@l'' = @l, ''@r'' = @r, ''@dt'' = @dt, ''@idr'' = @idr
    end
    if(@dt < @tdt)
        set @l = @id +1
    else
        set @r = @id
end
-- проверьте, есть ли у соседних записей лучшее совпадение
declare @t table(id bigint, dt datetime, dlt float)
insert @t(id, dt, dlt)
select top(1) <ID>, <DateTimeColumn>, abs(cast(<DateTimeColumn> as float) -cast(@tdt as float))
  from <Table>
 where <ID> < @idr
order by <ID> desc
insert @t(id, dt, dlt)
select top(1) <ID>, <DateTimeColumn>, abs(cast(<DateTimeColumn> as float) -cast(@tdt as float))
  from <Table>
 where <ID> > @idr
order by <ID>
insert @t(id, dt, dlt)
select @idr, @dt, abs(cast(@dt as float) -cast(@tdt as float))
select top(1) @dt = dt, @idr = id from @t order by dlt, id
select ''Found Value'' = @dt, ''Record Id'' = @idr
'
set @sql = replace(
            replace(
             replace(
              replace(
               replace(@sql, '<ID>', @ID),
              '<Table>', @Table),
             '<TargetDateTime>', convert(varchar(50), @TargetDateTime, 121)),
            '<debug>', @debug),
           '<DateTimeColumn>', @DateTimeColumn)
exec (@sql)