[modules]
;Модуль необходимый для работы с протоколом SIP
ysipchan.yate=yes
;Записываем звук
wavefile.yate=yes
;Формируем CDR
cdrbuild.yate=yes
;Этот модуль позволяет комбинировать в логах входяшие и исходящие
cdrcombine.yate=yes
;Подключаем муззон в линию
moh.yate=yes
;Удаленный вход
rmanager.yate=yes
;Модуль регистрации
register.yate=yes
;Тонегенератор
tonegen.yate=yes
;А вот и модуль для подключения внешних обработчиков(Perl, PHP, JS и прочее)
extmodule.yate=yes
;Модуль RTP
yrtpchan.yate=yes
;Шифруемся
openssl.yate=yes
;Эээ, ну пусть будет виртуальный канал
dumbchan.yate=yes
;Очень нужный модуль для отладки, - кроме подключения модуля,
;нужно саму откладку включить отдельно.
msgsniff.yate=yes
;Модуль парковки, собственно я им не пользуюсь, но пусть тут будет
park.yate=yes

;Здесь указываем наш обработчик, предварительно положив его в папку scripts
[scripts]
pbx_route.pl=
;Если нужно внешнее выполнение скриптов, поднимаем порт
[listener tcp5039]
type=tcp
addr=10.0.0.7
port=5039

#!/usr/bin/perl -w
#
use strict;
use warnings;
#Добавляем в @INC папки биллинга
BEGIN {
    use FindBin '$Bin';
    our $libpath = $Bin . '/../';
    my $sql_type = 'mysql';
    unshift( @INC,
        $libpath . "Abills/$sql_type/",
        $libpath . '/lib/',
        $libpath . "Abills/modules" );
}
use Abills::SQL;
#Подключаем либу для работы с Yate
use Pbx::Yate;
#Либа для работы с новыми таблицами в биллинге
use Pbx::Pbx;
my $message = Yate->new();
my $Pbx = Pbx->new($db, $message, \%conf);
#Инициализирум транки
trunks_init($message);
#Дальше идет инсталяция обработчиков событий
$message->install('call.answered', \&call_answered_handler, 50);
$message->install('call.route', \&call_route_handler);
$message->install_watcher('call.execute', \&call_execute_handler, 50);
$message->install('chan.hangup', \&chan_hangup_handler);
$message->install('chan.disconnected', \&chan_disconnected_handler, 10);
$message->install('chan.dtmf', \&chan_dtmf_handler, 50);
$message->install('user.auth', \&user_auth_handler);
#$message->install('user.authfail', \&user_authfail);
$message->install('user.register', \&user_register_handler);
$message->install('user.unregister', \&user_unregister_handler);
$message->install('user.notify', \&user_notify_handler);
$message->install_watcher("engine.timer", \&engine_timer_handler);
#Начинаем перехватывать сообщения
$message->listen();
sub trunks_init {
  my $message = shift;
  my ($attr) = @_;
  #Выбираем данные транков
  my $trunks = $Pbx->trunk_list({
    ACCOUNT      => '_SHOW',
    PROTOCOL     => '_SHOW',
    USERNAME     => '_SHOW',
    PASSWORD     => '_SHOW',
    REGISTRAR    => '_SHOW',
    LOCALADDRESS => '_SHOW',
    OUTBOUND     => '_SHOW',
    DOMAIN       => '_SHOW',
    ENABLED      => 1,
    INTERVAL     => '_SHOW',
    OPTIONS      => '_SHOW',
    COLS_NAME    => 1
  });
  if ($trunks) {
    foreach my $tr (@$trunks) {
      $message->message('user.login', undef, undef, %$tr );#Поключаем транк
    }
  }
}
#Ну и сам роутер
sub call_route_handler {
    my $message = shift;
    my $id = $message->param('id');
    my $called = $message->param('called');
    my $caller = $message->param('caller');
    #выкидываю плюс из номеров
    $called =~ s/\+//g;
    #определяем направление звонка
    my $call_type = ($Pbx->extensions_list({ NUMBER => $called, LIST2HASH => 'number,location' })) ? 'to_internal' : 'to_external';
    #Здесь проверяем наличие маршрута для звонка,
    #навешиваем на него дополнительные атрибуты и чистим память
    if ($Pbx->get_route($called)) {
      $message->params($Pbx->{params});
      $message->param('call_type', $call_type);
      $message->param('copyparams', 'maxcall,call_type,pbx_from');
      delete $Pbx->{params};
      return $Pbx->{location}
    }
    return 'noroute'
}
#Авторизуем пользователей
sub user_auth_handler {
    my $message = shift;
    my $user = $message->param('username');
    if ($user) {
      my $auth = $Pbx->extensions_list({ NUMBER => $user, PASSWORD => '_SHOW', COLS_NAME => 1 });
      if ($auth) {
        return $auth->{password};
      }
    }
    return undef;
}
#Обновляем данные регистрации в базе
sub user_register_handler($) {
    my $message = shift;
    $Pbx->update_location({
      LOCATION => $message->param('data'),
      CONN_ID  => $message->param('connection_id'),
      EXPIRES  => $message->param('expires'),
      NUMBER   => $message->param('number')
    });
    return 'true'
}
sub user_unregister_handler($) {
    my $message = shift;
    $Pbx->update_location({
      CONN_ID  => '',
      NUMBER   => $message->param('number')
    });
    return 'true'
}
#То же самое с транками
sub user_notify_handler($) {
    my $message = shift;
    my $account = $message->param('account');
    my $status = ($message->param('registered') ne 'false') ? 0 : 1;
    $Pbx->query2("UPDATE pbx_trunks SET status=$status WHERE account='$account';", 'do');
    return undef;
}

#Проигрываем звук в линию
#id - в какой линии работаем,
#replace - если звук уже играет, заменяем его
$message->message('chan.attach', undef,'',
  replace => 'true',
  source => "wave/play/hi.wav",
  notify => $id,
  id => $id
);
#Если необходимо организовать проигрываение нескольких файлов подряд
#нужно отслеживать событие 'eof', которое генерирует модуль wavefile.yate
#Для этого перед началом проигрывания звука инсталируем обработчик события 'chan.notify'
#Возможно есть более простое решение, я же реализовал так
my $handl;
$message->install('chan.notify', $handl = sub {
    $message->message('chan.attach', undef, '',
      replace => 'true',
      source => "wave/play/hi.wav",
      notify => $id,
      id => $id
    )
  }, 50, 'reason', 'eof');
#А вот так я реализовал звонок из вебинтерфейса.
#Оператор жмет кнопку вызова в карточке клиента, -
#поднимается виртуальный канал с него идет вызов
#на телефон оператора, а уже затем вызывается номер абонента
#caller в данном случае - номер вызываемого клиента
#так как именно этот номер потом будет отображаться в CDR
sub pbx_call {
  my ($attr) = @_;
  #получаем номер оператора
  my $info = $admin->list({
    SIP_NUMBER => '_SHOW',
    AID => $admin->{AID},
    COLS_NAME => 1
  });
  my $message = Yate->new();
  #Генерируем уникальный ID для канала
  my $msgid = $message->generate_id;
  #Тут подключаемся к порту, который ранее подняли в extmodule.conf
  $message->connect("10.0.0.7:5039");
  $message->message('call.execute', undef, $msgid,
    message    => 'call.execute',
    direct     => $Pbx->build_location($info->[0]->{sip_number}),
    caller     => $FORM{PHONE},#кому звоним, - забираем номер из формы клиента
    callto     => "dumb/",#тот самый виртуальный канал
    callback   => $FORM{PHONE},
    cdrwrite   => 'false',
    cdrtrack   => 'false',
    target     => $info->[0]->{sip_number},
  );
  return 1;
}